これはKarthik Chikmagalurさんによって記述された記事を日本語に翻訳した記事であり、記事の所有権と著作権はKarthik Chikmagalurさんに帰属します。

元の記事: Avy can do anything | Karthinks

Avyの使い方が間違っている

厳しすぎるだろうか？ 言い直そう。あなたはAvyのほとんどを使っていない。まだ言い過ぎだろうか？ よろしい、では扇動的ではないバージョンで言い直そう。 画面上を飛び回るEmacsパッケージであるAvyは、効率的に組み立て構成可能な使い方（デフォルトでは隠されている）に適しているパッケージなのだ。

説明はこれ位にしておこう。以下のデモでは複数のバッファーやウィンドウにたいして、手作業でカーソルを移動することなく、Avyのコマンド1つavy-goto-char-timerで様々な物事すべてを行う様子をお見せする：

テキストのコピー、行やリージョンのkill、テキストの移動、マーク、ヘルプバッファーの表示、定義の検索、Google検索、スペルチェックなど… まだまだある。

もう一度強調しておこう：Avyによって定義されるジャンプコマンドは数十個あるが、わたしが使うコマンドは1つだけだ。この記事ではあなたが自分用のバージョンを作れるようにこのコマンドを詳細まで掘り下げていくが、もっと重要なのはこれがなぜいかしたアイデアなのかという理由を説明することにある。

この記事はキーボードによって効果的にジャンプ移動するEmacsパッケージであるAvyに関するシリーズ2部作のうちのパート1となる。このパート1ではなんでもAvyで行うためにカスタマイズによるビルトイン機能の強化、あるいはそれに近いことに関して説明する。パート2では読者の個々のニーズに合わせてさらに複雑な機能を記述するために、より技術的（elispっぽい）な話題へと掘り下げていく予定だ。今回の記事に記載した短いスニペットに興味を感じたら、ここに1つのファイルとしてまとめてあるので参考にして欲しい。

フィルター→選択→アクション

主要目的がテキストをタイプすることではないEmacsとのやり取りのほとんどにおいて、同じパターンが繰り返されるのを目にする。あるタスクを実行するためにフィルター（filter：抽出）して、選択（select）して、それからアクション（act：実行）を順繰りに行うパターンのことだ。

フィルター：通常は何らかのテキストをタイプすることによって、大量に積まれたウィンドウ候補をより少ない候補へと絞り込む。以下に示す例のように候補は何でもよい。

選択：必要は候補いずれかを指定する（通常は視覚的な同意つき）。フィルターによって候補リストが1つの候補に絞り込まれた場合には自動的にそれを選択する。

アクション：引数としてその候補を渡してタスクを実行する。

• ファイルをオープンしたい? ならコマンドを呼び出してから補完リストをフィルターするテキストをタイプして補完結果から選択してからfind-fileだ。

• バッファーの切り替え? フィルターに何かをタイプ、バッファーを選択して切り替えるだけ。

• コード内のシンボルの自動補完はどうだろう? ポップアップリストを絞り込むための文字を数文字タイプして、候補を選択したら確認に同意すればいい。

例のごとく、これは単純化されたモデルだ。たとえばHelm、Ivy、Diredの仲間たちは処理する複数の候補をユーザーが選択できるようにしている。このアイデアを検討する間は、この知識は脇に避けておくことにしよう。

この観察によっていくつかの興味深いアイデアが導かれる。たとえばフィルター→選択→アクションというプロセスが、1つの操作と考えられることが珍しくない。フィルタリング、選択、アクションのフェーズを（コードや脳内で）分離してみれば、多くの可能性を考慮する自由が得られるだろう。以下はミニバッファーにおけるやりとり：

異なる補完スタイル（regexp、flex、あるいはorderlessによるマッチング）、異なる選択インターフェイス（Icomplete、Ivy、Helm、Vertico、Selectrumと日々増加中）、異なるアクションディスパッチャー（Embark、HelmやIvyのアクション）といった可能性が考えられる¹。シェルユーティリティ分野においてもfzfの登場以来、新たなユーティリティが次々と爆誕する様はさながらミニカンブリア爆発とでも形容したくなる勢いだ。Emacsにおけるミニバッファーとは、物事を選択する上でわたしたちが慣れ親しんだ場所なので、これらの例を考えるのは自然だろう。

この使用パターンはミニバッファーとの対話にかぎらず拡張できる。通常のバッファー操作において、フィルター→選択→アクションというパターンで物事を行うことは珍しいことではない。Emacsとのほとんどの（テキストのタイプに重点を置かない）対話において、この使い方を実際に目にできるだろう。ポイント（テキストカーソルのこと）が何らかのテキストにあるときにgoto-definitionコマンドを呼び出せば、フィルタリングのステップは飛ばしてthing-at-ptライブラリーの関数が選択を行い事前にセットされたアクションを行うのだ。マウスによる対話ならどうなるだろう？ アイコンだらけのウィンドウをスクロールしてかいくぐり、お目当てのアイコンにマウスカーソルを置いてクリックといった具合である。この完全に冗長な例から、より興味深いケースにたいする気づきが得られる。

Isearchで考えてみよう：

（C-sの後に）何かタイプすると、バッファーのテキストが自動的にフィルターされてもっとも近くにあるマッチが選択される。その後に続くマッチを順に選択したり、最初や最後のマッチにジャンプすることも可能だ。ここではマッチした位置へのカーソル移動というプロセスがアクションに相当するが、これは検索文字列にたいするoccurやquery-replaceの実行のような処理のうちの1つとみなすことができる。Isearchには多くはフィルターと選択、アクションを同時に行うコマンドが多く、そのためにユーザーは丸い穴に無理して四角い釘を打つような破目となる²。

Isearchの使用に少しでも時間を費やした経験があればIsearchの単一のタスクを、独自に構成可能な3つのフェーズに分割することで生じるトレードオフが理解できるはずだ。2つ、あるいは3つすべてを単一操作にまとめることが、Isearchにおけるキーボード操作を邪悪なまでに高速化する。わたしがIsearchを使用する際には、頭が指を追いかける場面が珍しくない。他方モジュール化がもつ優位な点は、その表現力にある。3つのフェーズからなるプロセスは全体として遅くはなるもののフィルター、選択、アクションそれぞれのスロットに異なるパーツを繋げることによって、さらに多くのことを行うことが可能になる。まったく異なるタスクにたいして、ミニバッファーがさまざま方法を用いていかにして処理をこなすか思い浮かべてみればわかるだろう！

話をIsearchに戻す。どうやれば3つのステージに分割できるのか? 根性が持続できれば大したことはないだろう。すべてがelispである以上、それは難しい注文ではないのだ。たとえばProtesilaos Stavrouはビデオにおいて、候補のマーキングといった直観的な多くのアクションをIsearchに追加している。しかし Avy の存在によってIsearchの修整が不要だということが明らかになった。フィルターというキラー機能を有しつつも、王者同様3つのステージを分離しているのがAvyである。Avyによって何とも興味がそそられる可能性が生みだされた。

待った、Avyとは？

Avyはabo-aboことOleh Krehelによって記述された。彼は実に多産な作者でありIvy、Counsel、Ace-Window、Hydra、Swiperを記述したのは彼であり、他にもおそらく読者も使ったことがあるEmacsのパッケージエコシステムの主要コンポーネントの多くも彼が記述した。この記事を読んでいる読者なら、すでにAvyを知っている（そして多分使ったことがある）かもしれない。したがってAvyのドキュメントから非常に短いバージョンを紹介しよう：

Avyとは文字ベースのデシジョンツリーを用いて可視なテキストにジャンプするためのGNU Emacs向けパッケージです。

Avyコマンドを呼び出して何かテキストをタイプしてみよう。フレーム（必要に応じてすべてのEmacsフレーム）上にあるテキストへのマッチすべてが選択のための候補となり、ヒント文字が上に重ねて表示される。ここ（訳注：このパラグラフの原文）で”an”と入力すると、これにマッチするフレーム上の文字列すべてがハイライト表示される：

ヒントのいずれかをタイプすれば、カーソルがその位置にジャンプする。以下のビデオでは別のウィンドウからこのセンテンスにジャンプしている：

テキストにマッチする位置に(ウィンドウ間を横断して)ジャンプ、その後はpop-global-mark（C-x C-SPC）で元の位置にジャンプして戻る、というのがAvyの典型的な使い方だろう。後半のセクションではじAvyを使った前方あるいは後方へのジャンプについて詳解する。以下のデモではAvyで2回ジャンプしてから順番にジャンプして戻るプロセスを行っている：

少なくとも、これが公式の説明だ。詳細についてはREADMEを参照してほしいが、わたしが疑問に思うのは……

Avyのドキュメントにはもっとも肝心な部分が記載されていない

Avyは自動的にフィルタリングを行い、文字ベースのデシジョンツリーを通じて選択を行う。これを3つのパートからなるわたしたちの対話モデルにどのように適合させるかを示そう。

フィルターして、

あなたがAvyを呼び出すまでは、 スクリーン上にあるすべてのテキスト文字列 が選択のための候補である。どれを選ぶかはすべてあなたに委ねられており、選べる選択肢が多すぎるくらいだ！

プールされた大量の候補からフィルタリングを行うのは、ミニバッファーでテキストをタイプすることによってフィルタリングを行う方法と似ている。これによりプールのサイズは、入力にマッチするサイズへと絞り込まれる。Avyは数十個のフィルタリングスタイルを提供している。使用できるスタイルはポイントより上または下の候補だけを考慮するスタイル、単語の先頭、カレントのウィンドウ（またはフレーム）、空白、行頭、あるいはOrgファイルのヘッダーだけを考慮するスタイルといった具合にリストはまだまだ続いていく。

• Avyのフィルタリングコマンド

これは追い続けるのが厳しい気狂いじみたリスト だ。

（当然ではあるが）Avyのフィルタリングは選択メソッドからは独立しているが、フィルタリングには軽い目眩を覚える程の量のコレクションが存在する。これはユーザーはもっとも頻繁に使うコマンドをいくつか選んで、選んだコマンドだけを記憶に刻むという仮定がもたらしたアイデアではないかとわたしは考えている。

ここで問題が生じる：わたしたちはエディター自体にではなく、テキストエディターで解決しようとしている問題にたいして精神的な帯域幅を使用したいのだ。無意識に行えない意思決定にはコストがかかり、集中力も乱されてしまう。現段階では物事を見つけて処理を行うためには、IsearchとAvyの中間点の何かを使ってその場で決定する必要がある。Swiper、Helm-swoop、Consult-lineといった多機能な検索ツールを使っている場合には、選べるオプションは3つだ。大量のAvyコマンドをトップに据えると、それが精神的な行き詰まりへと導くための処方箋になりかねない。すべての面においてもっとも適応力があり、柔軟かつ汎用的なAvyコマンドavy-goto-char-timerを選択するだけにしておけば、これを回避できるだろう。

(global-set-key (kbd "M-j") 'avy-goto-char-timer)

さらに以下では、常にIsearchを使用して必要に応じてAvyに切り替えることにより、この決定さえ不要だというわたしの考えを述べる。

明確にしておこう。それに忙殺されているように見えるもののAvyを使えば回避できる、慢性的かつ頻繁なコンテキスト切り替えによるコストが存在する。そのコストに見合ったコストであることが決定コストには要求されるものとする。ニーズにたいしてAvyの柔軟なフィルタリングオプションの調整を要するケースは存在する。Avyベースの候補（lintエラーからバッファー選択に至るすべて）にたいしてフィルタリングを提供する数々のパッケージの存在がその証拠だ。これについてはパート2で詳しく検討しよう。

とは言ったものの興味があるのは、まだ探求が済んでいないAvyの別の側面だ。以下の主張ではそれについても目を向けていこう。

選択して、

Avyが提供する選択メソッドには、すべてスクリーン上の位置にマッピングされた文字のタイプが含まれている。これはIsearchとは大きく異なる。isearch-repeat-forward（C-s、数プレフィックス引数が指定されているかもしれない）を呼び出すIsearch、補完バッファー（completions buffer）のナビゲーションにC-nやC-pを用いるミニバッファーとはまったく異なるのだ。Avyの選択メソッドは使用する文字シーケンスが最小となるようにデザインされており、わたしたちには40のキーに計算量オーダーO(1)でアクセス可能な10本の指が備わっているので、より高速であることが一般的だ。ジャンプしようとしている位置を直接見ていることが多いという事実は、ちんぷんかんぷんなスクリーン全体の解析が不要なことを意味している。この記事にとっては不幸ではあるが、スクリーンショットやデモを見るよりも、Avyを使ってみるほうが遥かに直観的であることをも意味している。

この洗練されたデザインによって、選択フェーズに手を加える理由はほとんどなくなった。選択フェーズは必要十分にモジュール化されているので、他のフィルターやアクションのステージに融通できる。選択に用いる文字集合や文字位置を変更したければ、Avyのスタイルをカスタマイズできる。候補選択に簡単な単語を用いる例を示す。

選択操作については第2部でも注目していく予定。

アクション！

という訳で、この記事の焦点をアクションに定めよう。Avyがゴールとして掲げているのは何かにジャンプすることである。これは（文脈的には）より高速化されたIsearchのように聞こえる。しかしジャンプすることは、Avyのもつ可能性のうちの1つに過ぎない。Avyは”ディスパッチリスト（dispatch list）”を提供する。これは候補にたいして実行可能なアクションのコレクションであり、すべてのアクションはジャンプアクションと同等に扱われる。これらのコマンドは、Avy使用中なら何時でも?で表示できる：

これはスクリーン上の任意の場所で実行したいアクションが何であれ、すべてのアクションがAvy独自のフィルタリングおよび選択のメソッドを自由に使用できることを意味する。わたしたちの対話モデルの終わり方は以下のようなブロックとなるだろう。

さらにAvyには、スクリーン上の何処かからテキストをコピーするのように、他のアクションを実行するいくつかのコマンドも定義されている：

このアプローチは拡張性において問題がある。 これらはそれぞれフィルター→選択→アクションという完全なプロセスを定義するコマンドなので、多様性や対応範囲で何らかの必要が生じたとしても、拡張の余地やキーボードの空きはすぐに枯渇してしまうだろう。動的な面においても不十分だ。一旦コマンドを開始してから気が変わっても、コマンド間をつなぐパイプラインが固定されているので変更できないのだ。

Vimの編集モデルが愛されるのには理由がある。M個のアクション（動詞）とN個のカーソル移動を知ることによって、M×N個の合成操作を得られるミニ言語であることがその理由だ。（M+N）の知識から（M×N）の結果が得られるという比率関係により、Vimで動詞や移動の習得に努力を費やせば、その見返りとして得られる報酬が二次関数的に増加するからだ。この理由によりAvyのVimバージョンに相当するEasymotion³には、合成機能の一部が組み込まれている。この機能を部分的にAvyに導入する方法を見つけられれば、動詞と移動の組み合わせよりも多くのことを行える筈なのだ（こっちはEmacsなのだから）。これを達成するためにAvyのソースコードに分け入る必要はない。すでに必要なフックはすべて揃っている。

Avyのアクション

Avyにおいて任意のアクションを実行する際の基本的な使い方は以下のとおり：

1. Avyのコマンドを呼び出す。どのコマンドでもよいが、わたしはavy-goto-char-timerの一択。

2. フィルター：スクリーン全体からいくつかの位置に候補を絞り込むためのテキストを何かタイプする。

3. 選択：実行したいアクションを指定する。?でディスパッチのヘルプを表示できる。正しくセットアップしてあれば不要だが、詳細が知りたければ『Avyにたいする心構え』を参照のこと。

4. アクション：アクションを実行したい候補を1つ選ぶ。

以下はわたしがAvyで頻繁に行うことの一部。アクティブなウィンドウにかぎらず、フレーム内のすべてのテキスト行えることに注目！

まずはAvyを用いて一般的な編集アクションを行う際の悩みの種を解消する。VimとEasymotionを使っていれば、以下のアクションのうち最初のいくつかは無料で入手できる：

単語、sexp、行の候補のkill

単語とsexpのkillについてはビルトイン。行のkillはわたしが追加した。このデモでは手っ取り早くtypo修整とコメント削除を行い、その後に別ウィンドウのコードを削除している：

(defun avy-action-kill-whole-line (pt)
  (save-excursion
    (goto-char pt)
    (kill-whole-line))
  (select-window
   (cdr
    (ring-ref avy-ring 0)))
  t)

(setf (alist-get ?k avy-dispatch-alist) 'avy-action-kill-stay
      (alist-get ?K avy-dispatch-alist) 'avy-action-kill-whole-line)

単語、sexp、行の候補のyank

killリングまたはバッファーのポイント位置にコピーする。このデモではmanページからファイルにテキストをコピーしている：

(defun avy-action-copy-whole-line (pt)
  (save-excursion
    (goto-char pt)
    (cl-destructuring-bind (start . end)
        (bounds-of-thing-at-point 'line)
      (copy-region-as-kill start end)))
  (select-window
   (cdr
    (ring-ref avy-ring 0)))
  t)

(defun avy-action-yank-whole-line (pt)
  (avy-action-copy-whole-line pt)
  (save-excursion (yank))
  t)

(setf (alist-get ?y avy-dispatch-alist) 'avy-action-yank
      (alist-get ?w avy-dispatch-alist) 'avy-action-copy
      (alist-get ?W avy-dispatch-alist) 'avy-action-copy-whole-line
      (alist-get ?Y avy-dispatch-alist) 'avy-action-yank-whole-line)

フレームのどこかから行やリージョンをコピーするために、実際にはavy-copy-lineおよびavy-copy-regionというコマンドをAvyが個別に定義している。これらのコマンドの方が関数呼び出しにアクションステージが織り込み済みなので僅かに速いので、そちらを使うほうがよいかもしれない。しかし多すぎるトップレベルコマンドを記憶することによる精神的な燃え尽き症候群をわたしたちは避けたいので、avy-goto-char-timerを呼び出して（フィルターと選択）、その後にお目当ての候補を選択してディスパッチを行うという、よりシンプルな2つのステージで作業を行っている。

単語、sexp、行の候補の移動

これはAvyでは”teleport”、わたしは”transpose”と呼んでいるが、いずれにせよtにバインドされることになる。このデモではバッファーのあちこちをあまり移動せずに、バッファーのあちこちにテキストを移動する。

(defun avy-action-teleport-whole-line (pt)
    (avy-action-kill-whole-line pt)
    (save-excursion (yank)) t)

(setf (alist-get ?t avy-dispatch-alist) 'avy-action-teleport
      (alist-get ?T avy-dispatch-alist) 'avy-action-teleport-whole-line)

候補の位置までzap

これはビルトインのコマンドで、デフォルトではzにバインドされている。

単語やsexpの候補をマーク

これもビルトインのコマンドであり、デフォルトではmにバインドされている。Avyを使って候補にジャンプするのは、mark-sexpを呼び出すジャンプと変わらないが、Avyの方がより使いやすくなっている：

ポイントから候補までのリージョンをマーク

Avyジャンプする前にマークをセットするので、C-x C-xを使用してリージョンをアクティブにすることも可能だが、このコマンドを使うほうがトラブルを回避できるだろう。

(defun avy-action-mark-to-char (pt)
  (activate-mark)
  (goto-char pt))

(setf (alist-get ?t avy-dispatch-alist) 'avy-action-mark-to-char
      (alist-get ?T avy-dispatch-alist) 'avy-action-teleport-whole-line)

Avyにより自動的に実行される、コンテキストに応じたアクションをいくつか示そう：

候補の単語にispell

これはビルトインのコマンドであり、デフォルトではiにバインドされている。

このプロセスを自動化するために、一番上にある修整を自動的に採用するバージョンで、avy-action-ispell（ビルトイン）を置き換えることもできる。

(defun avy-action-flyspell (pt)
  (save-excursion
    (goto-char pt)
    (when (require 'flyspell nil t)
      (flyspell-auto-correct-word)))
  (select-window
   (cdr (ring-ref avy-ring 0)))
  t)

;; セミコロンにバインド (flyspellが使用するのはC-;)
(setf (alist-get ?\; avy-dispatch-alist) 'avy-action-flyspell)

単語の定義

わたしはEmacsのdictionaryパッケージを使っているので、単語の登録は怠けがちだ：

;パッケージマネージャーを変えたりお気に入りの辞書パッケージに変えてもよい
(package-install 'dictionary)

(defun dictionary-search-dwim (&optional arg)
  "ポイント位置の単語の定義を検索する。
リージョンがアクティブなら、そのリージョンのコンテンツを検索する。
プレフィックス引数とともに呼び出した場合には、検索する単語の入力を求める。"
  (interactive "P")
  (if arg
      (dictionary-search nil)
    (if (use-region-p)
        (dictionary-search (buffer-substring-no-properties
                            (region-beginning)
                            (region-end)))
      (if (thing-at-point 'word)
          (dictionary-lookup-definition)
        (dictionary-search-dwim '(4))))))

(defun avy-action-define (pt)
  (save-excursion
    (goto-char pt)
    (dictionary-search-dwim))
  (select-window
   (cdr (ring-ref avy-ring 0)))
  t)

(setf (alist-get ?= avy-dispatch-alist) 'dictionary-search-dwim)

シンボルのドキュメントを調べる

;パッケージマネージャーの置き換えや別のヘルプライブラリーの選択も可
(package-install 'helpful)

(defun avy-action-helpful (pt)
  (save-excursion
    (goto-char pt)
    (helpful-at-point))
  (select-window
   (cdr (ring-ref avy-ring 0)))
  t)

(setf (alist-get ?H avy-dispatch-alist) 'avy-action-helpful)

単語やsexpにたいするGoogle検索⁴

Googleを検索できるEmacs機能が必要になるだろう。いくつか存在するが、わたしが使っているTuxiという名前のCLIプログラムはとても便利だ:

さて、信じ難いほど難解なコンテキスト向けのアクションをこなす関数を、avy-dispatch-alistに追加し続けることも可能ではあるが、ひとまず一歩下がってみよう。わたしたちが望んでいるのは意味的にクラス分けされているバッファーテキストにたいして、簡単に呼び出すことが可能なアクションのリストだった。これに似た何かを以前どこかで目にしたことはないだろうか？

Avy + Embark: どこでもAnyアクション

AvyとEmbarkはレゴブロックのように互いに接続させることができる。例をいくつか示そう：

出現位置のハイライト

このデモでは細部まで記述されたLaTeXドキュメントの一部のキーワードをハイライトして、その後に手作業でカーソルを移動するのではなく、AvyとEmbarkを用いて引用キーから参考文献にアクセスしている：

Emacsのヘルプシステムで複雑なもつれを切り抜ける

このデモではパッケージで何かを探す際にAvyとEmbarkを使ってhelp、apropos、customizationのバッファーを結びつける。ここでも手動でのカーソル移動は行わない。

責任の分担

ここではわたしたち自身がもつ大量の冗長性と指に教え込んだ記憶を節約する。Avyには独自のフィルタリング手段を提供してもらい、Embarkには自分のベストを尽くすこと、すなわちアクションを実行してもらうのだ！ 候補選択における中間的な作業はAvyとEmbarkで共有して行ってもらおう。Avyが候補の一般的な位置を指定して、その位置でアクションを行う際の意味的単位の解決はEmbarkが行う。Avyによってフィルター→選択→アクションというプロセスが使いやすいようにchunk化（訳注：あるものをより小さな断片に分割したり、より大きな断片にまとめすること）されているので、2つを統合するために必要なelispは簡単なもので事足りるはずだ⁵。

(defun avy-action-embark (pt)
  (unwind-protect
      (save-excursion
        (goto-char pt)
        (embark-act))
    (select-window
     (cdr (ring-ref avy-ring 0))))
  t)

(setf (alist-get ?. avy-dispatch-alist) 'avy-action-embark)

アクションを行う単位としてEmbarkが採用した候補が気に入らなければ、他のターゲットに巡回するためにembark-cycleを呼び出すことができる。

これまではすべて、ポイントを動かすことさえ行っていない⁶。

Avy + Isearch: 探してジャンプ

IsearchとAvyにはお互い違う強みがある。Avyは任意のウィンドウ上にある可視の要素すべて、Isearchはバッファー内の任意のマッチ候補に素早くジャンプできる。ある程度の距離範囲をジャンプしたければAvy、短距離または非常に長い距離を移動したければIsearchが適しているだろう。すでに視界にターゲットを収めている場合にはAvyが役に立つし、何かを探している場合にはIsearchが便利だ。しかしいずれか一方を選ぶ必要はない。Avy候補プールIsearchの候補に制限すれば、2つを簡単に組み合わせることができるからだ。こうすればIsearchを開始してAvyで完了できる:

(define-key isearch-mode-map (kbd "M-j") 'avy-isearch)

繰り返す。2つのコマンドのいずれかを呼び出すかを毎回意識的に判断するのは悪いアイデアだ。常にIsearch呼び出して、必要に応じてAvyを呼び出すというのなら悪くないが。

少なくとも、これが通常のピッチだろう。

ただしわたしたちにとって説明の中の”ジャンプ”は”アクション”に置き換えられる。Isearchの可視な候補であればどれでにたいしても、上述したいずれかのアクションを適用できる。Isearchのマッチとマッチの間のテキストのkill？ ある単語を含む前の行をカレント位置にコピー？ 試してみよう。要するにIsearchからフィルター以外の2つのアクションを間接的に切り離してフィルタリングと選択を行い、Avyでアクションを行えばよいのだ。

Avyが賢すぎるとき

今度のパターンには失敗モードがある。マッチが1つしかなければ、その位置にAvyがジャンプするだけでアクションは何も提案しないのだ。あらら…

1つだけのマッチにたいして選択用のヒント/文字を表示するようAvyに強いることも可能だが、デフォルトのDWIMを選択する挙動のほうが通常は望ましいだろう。その場合に考え得るはオプションが2つある：

• たとえば1文字をタイプするといったような保守的な方法によって候補をフィルタリングする。avy-goto-charやavy-goto-char-2を使えば、ほとんど常に2つ以上のマッチを得られるので、この問題は回避できる。timerベースのAvyコマンドのいずれかを使えば、フィルターにどのくらいのテキストを用いるかをその場で変更できる。

• ジャンプしたら昔ながらの方法でアクションを実行して、その後はAvyがセットしたマークpopして元の位置にジャンプして戻る。これはデフォルトのset-mark-command (C-u C-SPC)で行うことができる⁷。これはポイントをジャンプさせるようなほとんどのコマンド（Isearchも含む）で行うことが可能だ。Vimユーザーならジャンプリスト（jumplist）へのアクセスはC-o、変更リスト（changelist）はgでアクセスできる。

以下のデモはテキストを編集するためにAvyで2回ジャンプ、それから連鎖的にジャンプを辿って開始位置に戻っている：

ところでポイントとは何ぞや?

これは知識をひけらかしたい人向けのセクションだ。

この記述では”ポイント”と”カーソル”を互いに置き換え可能な用語として用いてきた。これら2つ用語の定義の違いについては理解している。

Avyを用いることで得られる利点として、カーソルを移動せずにアクションを実行するテキストのフィルタリングと選択を行えることが証拠の1つとして挙げられる。しかしこれまで示してきたコードスニペットのsave-excursionブロックによりポイントを移動しないのではなく、単にほとんど不可視な状態でポイントを移動していたことが明らかになった。ポイントがあるのはEmacsのgap-bufferと呼ばれるデータ構造体の中であり、Emacsのコマンドはすべてそのポイントを中心に動作することを指向しているし、通常はその方が効率的なのだ。

正にその通り。other-windowを呼び出してからテキストをIsearch、アクションを実行して戻るよりも、別のウィンドウにあるテキストにたいして任意のAvyアクションを実行するほうがより高速だ。しかしわたしにとってポイント(har)は、elispを記述に役に立つ抽象化なのだ（訳注：harはポイントを実際に実装するgapではなくハードウェアポイント、つまりカーソル位置と等価な意味でのポイントを強調するためだと思われる）。フレーム全体のコンテンツについて、フィルター→選択→アクションという強力なパラダイムで考えさせてくれることがAvyの真価だ。意識的にウィンドウやフレームを移動することで生じる精神的なコンテキストスイッチなしで操作を行うことができるという事実は、ボーナスのようなものだろう。

Avyにたいする心構え

Avyでスクリーン上を飛び回るのは、マウスを使うのとある点似ている。その見地からマウスのほうが速いので好ましいと主張するのは簡単だ。この組み合わせにアクションのディスパッチを追加すれば、この不公平な比較は消失する。他のウィンドウからの行のyankやスクリーン向こう端のシンボルにたいするgoto-definitionの実行では、マウスによる選択/右クリック稼業よりAvyのほうが遥かに高速だ。そもそもこれこそが頻繁なコンテキストスイッチによる破壊的効果の勘定を抜きにしても、キーボード（もし可能ならマウスでも）で全操作を行うことを好む理由なのだ。

嗅覚テスト

あなたがすでにAvyのジャンプを使っていたとしても、Avyのクションの使用はスクリーン上のテキストとのやりとりにおける新たな手段だろう。Avyアクションの使用や新たなアクションを発見する心構えとして、わたしはEmacsの日常的な使い方の“匂い”を探すよう努めている：

• テキストにカーソルを合わせるためにウィンドウを何回か切り替えている
• Isearchで正しいマッチにたどり着くために4個以上のマッチをジャンプしている
• 何かを調べるコマンドを実行するためにポイントを長距離移動している
• 毎回C-SPCによる手作業でマークをアクティブにしている
• 単語1つの削除のために場所をジャンプしている

キーマップに埋もれて

“Avyにたいする心構え”には別の意味がある。シンプルなテキスト編集の上に新たな抽象化レイヤーを積み重ねるということは、新たにキーマップを学ぶ必要があることをも意味しているのだ。Emacsのキーマップに関してはすでに多すぎるというのに！

これは真実だが自分にとって道理に適ったキーを選択することで、労力は大幅に軽減されるだろう。これまでのコードスニペットでは、わたしのEmacsのキーバインディング（ほぼデフォルト）を真似たので、新たに何かを覚える必要はないはずだ：

ニーモニックに留めず通常の編集で使うのと同じキーバインディングを再利用するだけだ。若干長目のキーシーケンスという犠牲を払うことによって、指に覚えさせた記憶を最大限に再利用できる。Embarkユーザーであれば上記のキーすら必要なくなる。必要なのはembark-actの呼び出しだけだ。

未解決問題

一般的な編集においてポイントをどこか(別のウィンドウかもしれない)へ移動する際に、依然として手作業を要するアクションが2つ存在する：

• スクリーンの境界を超えた別ウィンドウのコンテンツにたいする検索やジャンプ。これにはシンプルな解決策がある：

(defun isearch-forward-other-window (prefix)
    "Function to isearch-forward in other-window."
    (interactive "P")
    (unless (one-window-p)
      (save-excursion
        (let ((next (if prefix -1 1)))
          (other-window next)
          (isearch-forward)
          (other-window (- next))))))

(defun isearch-backward-other-window (prefix)
  "Function to isearch-backward in other-window."
  (interactive "P")
  (unless (one-window-p)
    (save-excursion
      (let ((next (if prefix 1 -1)))
        (other-window next)
        (isearch-backward)
        (other-window (- next))))))

(define-key global-map (kbd "C-M-s") 'isearch-forward-other-window)
(define-key global-map (kbd "C-M-r") 'isearch-backward-other-window)

C-M-vで他のウィンドウのスクロールしながら、そのウィンドウに切り替えずにC-M-sでIsearchできる⁸。冒険してみたければ、上記関数の(other-window next)を(ace-window)に置き換えてみよう。

基本的には他のウィンドウのバッファーにある任意のテキストにたいして、以前と同じようにIsearchからAvyを呼び出すことができる。

• リージョンのテキストのコピー。これにはavy-copy-regionというAvyベースの解決策がある。とは言え、必要なのはAvyコマンドを1回呼び出すだけ、というのが冒頭の約束だった。現時点ではAvyだけで短いジャンプを繰り返すか、あるいはIsearchAvyを使うという退屈な方法でこれを行うことになるだろう。もっとelispっぽい解決策については、この記述のシリーズ第2弾を待ってほしい。

この記事はEmbarkの使用方法に関する記事のアイデアと関連しているので、主にアクションについて記述されている。しかしAvyはモジュールの組み合わせにより構成されているので、フィルター→選択によって機能するさまざまなアプリケーションの広い範囲に適性がある。シリーズ第2弾ではAvyのAPI、および独自コマンドを作成する方法についても掘り下げていくつもりだ。

脚注